Pokud máte blok TRY/CATCH, pak je pravděpodobnou příčinou to, že zachycujete výjimku přerušení transakce a pokračujete. V bloku CATCH musíte vždy zaškrtnout XACT_STATE()
a zpracovávat příslušné přerušené a nezávazné (odsouzené) transakce. Pokud váš volající zahájí transakci a calee se dostane, řekněme, do uváznutí (které transakci přerušilo), jak bude volaný sdělovat volajícímu, že transakce byla přerušena a nemělo by pokračovat „obchodem jako obvykle“? Jediným možným způsobem je znovu vyvolat výjimku a donutit volajícího situaci řešit. Pokud v tichosti spolknete přerušenou transakci a volající pokračuje v domnění, že je stále v původní transakci, může to zajistit pouze chaos (a chybou, kterou dostanete, je způsob, jakým se motor snaží chránit sám sebe).
Doporučuji vám projít si Zpracování výjimek a vnořené transakce který ukazuje vzor, který lze použít s vnořenými transakcemi a výjimkami:
create procedure [usp_my_procedure_name]
as
begin
set nocount on;
declare @trancount int;
set @trancount = @@trancount;
begin try
if @trancount = 0
begin transaction
else
save transaction usp_my_procedure_name;
-- Do the actual work here
lbexit:
if @trancount = 0
commit;
end try
begin catch
declare @error int, @message varchar(4000), @xstate int;
select @error = ERROR_NUMBER(), @message = ERROR_MESSAGE(), @xstate = XACT_STATE();
if @xstate = -1
rollback;
if @xstate = 1 and @trancount = 0
rollback
if @xstate = 1 and @trancount > 0
rollback transaction usp_my_procedure_name;
raiserror ('usp_my_procedure_name: %d: %s', 16, 1, @error, @message) ;
end catch
end
go