Hibernate Šifrování databáze Zcela transparentní pro aplikace

Pokud ukončíte práci v aplikaci, můžete použít vlastní typy Hibernate a do vašeho kódu by to nepřidalo tolik změn.

Zde je vlastní typ šifrovaného řetězce, který jsem použil:

import org.hibernate.usertype.UserType
import org.apache.log4j.Logger

import java.sql.PreparedStatement
import java.sql.ResultSet
import java.sql.SQLException
import java.sql.Types

class EncryptedString implements UserType {

  // prefix category name with 'org.hibernate.type' to make logging of all types easier
  private final Logger _log = Logger.getLogger('org.hibernate.type.com.yourcompany.EncryptedString')

  Object nullSafeGet(ResultSet rs, String[] names, Object owner) throws SQLException {
    String value = rs.getString(names[0])

    if (!value) {
      _log.trace "returning null as column: $names[0]"
      return null
    }

    _log.trace "returning '$value' as column: $names[0]"
    return CryptoUtils.decrypt(value)
  }

  void nullSafeSet(PreparedStatement st, Object value, int index) throws SQLException {
    if (value) {
      String encrypted = CryptoUtils.encrypt(value.toString())
      _log.trace "binding '$encrypted' to parameter: $index"
      st.setString index, encrypted
    }
    else {
      _log.trace "binding null to parameter: $index"
      st.setNull(index, Types.VARCHAR)
    }
  }

  Class<String> returnedClass() { String }

  int[] sqlTypes() { [Types.VARCHAR] as int[] }

  Object assemble(Serializable cached, Object owner) { cached.toString() }

  Object deepCopy(Object value) { value.toString() }

  Serializable disassemble(Object value) { value.toString() }

  boolean equals(Object x, Object y) { x == y }

  int hashCode(Object x) { x.hashCode() }

  boolean isMutable() { true }

  Object replace(Object original, Object target, Object owner) { original }
}

a na základě toho by mělo být jednoduché vytvářet podobné třídy pro int, long atd. Chcete-li to použít, přidejte do uzávěrky mapování typ:

class MyDomainClass {

  String name
  String otherField

  static mapping = {
    name type: EncryptedString
    otherField type: EncryptedString
  }
}

Vynechal jsem metody CryptoUtils.encrypt() a CryptoUtils.decrypt(), protože to není specifické pro Grails. Používáme AES, např. "Šifra =Cipher.getInstance('AES/CBC/PKCS5Padding')". Ať už použijete cokoli, ujistěte se, že se jedná o dvoucestnou kryptoměnu, tj. nepoužívejte SHA-256.