Oracle PL/SQL:Export dat z tabulky do CSV

Přečtěte si, jak používat UTL_FILE balíček pro export dat z tabulky do souboru CSV v Oracle PL/SQL.

V Oracle je to balíček UTL_FILE obsahuje mnoho procedur a funkcí pro psaní textového souboru. Níže jsou uvedeny podrobnosti o syntaxi a nezbytné kroky k zápisu souboru:

Syntaxe a kroky k zápisu souboru pomocí UTL_FILE

-- Declare a variable to store file type
n_file UTL_FILE.FILE_TYPE;
-- Open the file in Begin section, it will open the file and return the file handle into the variable n_file
n_file := UTL_FILE.FOPEN('DIR_OBJ', 'YourCSVFileName.csv', 'w', 4000);
-- Write a single or multiple lines
UTL_FILE.PUT_LINE(n_file, 'abc, xyz, xxx');
-- Close the file
UTL_FILE.FCLOSE(n_file);

Základní příklad

Declare
   n_file Utl_File.File_Type;
Begin
   -- The directory object MY_DIR must be exist or create a new one
   n_file := Utl_File.Fopen('MY_DIR', 'myfile.csv', 'w', '4000');

   Utl_File.Put_Line(n_file, 'First line.');
   Utl_File.Put_Line(n_file, 'Second line.');
   Utl_File.Put_Line(n_file, 'Third line.');

   Utl_File.Fclose(n_file);
End;

Jak jsem zmínil ve výše uvedeném příkladu, objekt adresáře MY_DIR musí existovat. Objekt adresáře v Oracle je odkaz na fyzický adresář na serveru. Následuje příklad vytvoření objektu adresáře v Oracle:

-- Windows example
CREATE OR REPLACE DIRECTORY CSVDIR AS 'd:\oracle\csvfiles';
-- Linux example
CREATE OR REPLACE DIRECTORY CSVDIR AS '/usr1/oracle/csvfiles';

Chcete-li se dozvědět více o objektu adresáře v Oracle, podívejte se na tento odkaz.

Export dat z tabulky do CSV v příkladu Oracle

Následuje příklad uložené procedury v Oracle, která exportuje data z tabulky EMP do souboru CSV:

Create Or Replace Procedure exp_emp_data Is

    n_file     utl_file.file_type;
    v_string   Varchar2(4000);
   
  -- get the data using cursor 
  Cursor c_emp Is
    Select
        empno,
        ename,
        deptno,
        sal,
        comm
    From
        emp;

Begin
    n_file := utl_file.fopen('CSVDIR', 'empdata.csv', 'w', 4000);

-- if you do not want heading then remove below two lines
    v_string := 'Emp Code, Emp Name, Dept, Salary, Commission';
    utl_file.put_line(n_file, v_string);
    
    -- open the cursor and concatenate fields using comma
    For cur In c_emp Loop
        v_string := cur.empno
                    || ','
                    || cur.ename
                    || ','
                    || cur.deptno
                    || ','
                    || cur.sal
                    || ','
                    || cur.comm;
        
        -- write each row
        utl_file.put_line(n_file, v_string);
    End Loop;
    
    -- close the file
    utl_file.fclose(n_file);
Exception
    When Others Then
        -- on error, close the file if open
        If utl_file.is_open(n_file) Then
            utl_file.fclose(n_file);
        End If;
End;

Nyní je vaše uložená procedura vytvořena, spusťte ji pro export dat:

Begin
    exp_emp_data;
End;

Související výukové programy:

• Nástroj:Generování procedury PL/SQL pro export dat z tabulky