Jak uložit BLOB jako soubor v PL/SQL?

Zde uvádím příklad uložení dat BLOB jako souboru v PL/SQL. Data BLOB můžete získat z tabulky se sloupcem BLOB nebo je můžete získat ze souboru na disku.

Příklad funkce PL/SQL pro uložení BLOB jako souboru

Níže uvedený postup má následující tři argumenty:

1. Název objektu adresáře Oracle (jako i_dir).
2. Uložit jako název souboru (jako i_file).
3. Data BLOB (jako i_blob).

CREATE OR REPLACE PROCEDURE blob_to_file (i_dir    IN VARCHAR2,
                                          i_file   IN VARCHAR2,
                                          i_blob   IN BLOB)
AS
   l_file       UTL_FILE.file_type;
   l_buffer     RAW (32767);
   l_amount     BINARY_INTEGER := 32767;
   l_pos        INTEGER := 1;
   l_blob_len   INTEGER;
BEGIN
   l_blob_len := DBMS_LOB.getlength (i_blob);

   l_file :=
      UTL_FILE.fopen (i_dir,
                      i_file,
                      'WB',
                      32767);

   WHILE l_pos < l_blob_len
   LOOP
      DBMS_LOB.read (i_blob,
                     l_amount,
                     l_pos,
                     l_buffer);
      UTL_FILE.put_raw (l_file, l_buffer, TRUE);
      l_pos := l_pos + l_amount;
   END LOOP;

   UTL_FILE.fclose (l_file);
EXCEPTION
   WHEN OTHERS
   THEN
      IF UTL_FILE.is_open (l_file)
      THEN
         UTL_FILE.fclose (l_file);
      END IF;

      RAISE;
END blob_to_file;

Test

Následující blok PL/SQL zavolá výše uvedený postup předáním objektu adresáře Oracle, názvu souboru a dat BLOB. Pro data BLOB používám funkci GET_BLOB, pro kterou jsem uvedl příklad ve svém předchozím příspěvku na blogu:Získat BLOB ze souboru v PL/SQL. V níže uvedeném případě získá data BLOB ze souboru myfile.jpg z umístění MY_DIR a uloží je do souboru abc.jpg v umístění IMG_DIR.

DECLARE
   f_blob   BLOB;
BEGIN
   /* check the above mentioned link for get_blob function example */
   f_blob := get_blob ('MY_DIR', 'myfile.jpg');
   /* now pass the blob to blob_to_file procedure to save it as a file */
   blob_to_file ('IMG_DIR', 'abc.jpg', f_blob);
END;

Nyní můžete zkontrolovat umístění adresáře IMG_DIR pro soubor vytvořený pomocí BLOB.

Viz také:

• Jak vytvořit objekt Oracle Directory Object?
• Zjistěte, jak extrahovat data BLOB z tabulky Oracle pomocí Toad