mohu udržovat jednu relaci Oracle ze dvou klientů oci?

Pokud používáte databázi 11g, můžete použít DBMS_XA balíček aby se jedna relace mohla připojit k transakci zahájené první relací. Jak ukazuje Tim Hall, můžete zahájit transakci v jedné relaci, připojit se k transakci z jiné relace a číst nepotvrzené změny provedené v transakci. Bohužel to však nepomůže s proměnnými relace (za předpokladu, že "proměnná relace" znamená proměnnou balíčku, která má rozsah relace).

Vytvořte balíček a tabulku:

CREATE TABLE foo( col1 NUMBER );

create or replace package pkg_foo
as
  g_var number;
  procedure set_var( p_in number );
end;

create or replace package body pkg_foo
as
  procedure set_var( p_in number )
  as
  begin
    g_var := p_in;
  end;
end;

V relaci 1 zahájíme globální transakci, nastavíme proměnnou balíčku a vložíme řádek do tabulky před pozastavením globální transakce (což umožňuje další relaci, aby ji mohla obnovit)

SQL> ed
Wrote file afiedt.buf

  1  declare
  2    l_xid dbms_xa_xid := dbms_xa_xid( 1 );
  3    l_ret integer;
  4  begin
  5    l_ret := dbms_xa.xa_start( l_xid, dbms_xa.tmnoflags );
  6    pkg_foo.set_var(42);
  7    dbms_output.put_line( 'Set pkg_foo.g_var to ' || pkg_foo.g_var );
  8    insert into foo values( 42 );
  9    l_ret := dbms_xa.xa_end( l_xid, dbms_xa.tmsuspend );
 10* end;
SQL> /
Set pkg_foo.g_var to 42

PL/SQL procedure successfully completed.

V relaci 2 pokračujeme v globální transakci, čteme z tabulky, čteme proměnnou relace a ukončujeme globální transakci. Všimněte si, že dotaz na tabulku vidí řádek, který jsme vložili, ale změna proměnné balíčku není viditelná.

SQL> ed
Wrote file afiedt.buf

  1  declare
  2    l_xid dbms_xa_xid := dbms_xa_xid( 1 );
  3    l_ret integer;
  4    l_col1 integer;
  5  begin
  6    l_ret := dbms_xa.xa_start( l_xid, dbms_xa.tmresume );
  7    dbms_output.put_line( 'Read pkg_foo.g_var as ' || pkg_foo.g_var );
  8    select col1 into l_col1 from foo;
  9    dbms_output.put_line( 'Read COL1 from FOO as ' || l_col1 );
 10    l_ret := dbms_xa.xa_end( l_xid, dbms_xa.tmsuccess );
 11* end;
SQL> /
Read pkg_foo.g_var as
Read COL1 from FOO as 42

PL/SQL procedure successfully completed.

Pro sdílení stavu relace mezi relacemi by bylo možné použít globální kontext aplikace místo použití proměnných balíčku? Můžete to zkombinovat s DBMS_XA balíčky, pokud chcete číst jak tabulky databáze, tak stav relace.

Vytvořte kontext a balíček pomocí getter a setter

CREATE CONTEXT my_context
  USING pkg_foo
  ACCESSED GLOBALLY;

create or replace package pkg_foo
as
  procedure set_var( p_session_id in number,
                     p_in         in number );
  function get_var( p_session_id in number )
    return number;
end;

create or replace package body pkg_foo
as
  procedure set_var( p_session_id in number,
                     p_in         in number )
  as
  begin
    dbms_session.set_identifier( p_session_id );
    dbms_session.set_context( 'MY_CONTEXT', 'G_VAR', p_in, null, p_session_id );
  end;
  function get_var( p_session_id in number )
    return number
  is
  begin
    dbms_session.set_identifier( p_session_id );
    return sys_context('MY_CONTEXT', 'G_VAR');
  end;
end;

V relaci 1 nastavte hodnotu kontextové proměnné G_VAR na 47 pro relaci 12345

begin
  pkg_foo.set_var( 12345, 47 );
end;

Nyní může relace 2 číst hodnotu z kontextu

  1* select pkg_foo.get_var( 12345 ) from dual
SQL> /

PKG_FOO.GET_VAR(12345)
----------------------
                    47