Manipulace se sbírkami

V druhém případě jste alespoň ztratili definici tabulky. Toto prohlášení:

create or replace TYPE tbl_list2 IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));

deklaruje pouze typ objektu (nebo záznamu), nikoli tabulku.

Takže to musíte udělat ve 2 krocích:

create or replace TYPE tbl_list_rec IS OBJECT (l_owner  VARCHAR2(64),l_name  VARCHAR2(64));
/

create or replace TYPE tbl_list2 as table of tbl_list_rec;
/

Poté potřebujete nějaké opravy syntaxe ve skriptu:

declare
  l_object tbl_list2;
  i        number;
begin
  -- for list initialization it must be filled with constructed objects
  l_object := tbl_list2( tbl_list_rec('','') );

  for i in 1..100000 loop          

    -- 1. select values to variable
    -- 2. Fix constructor for list 
    select 
      l_object MULTISET UNION DISTINCT tbl_list2(tbl_list_rec('myOwner','MyTable'))
    into 
      l_object 
    from 
      dual;

    end loop;

    for i in l_object.first ..  l_object.last loop
      -- output separate fields, there are now default conversion from 
      -- user-defined objects to varchar2.
      dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
    end loop;  

end;
/

AKTUALIZACE

Výše uvedené řešení je relativně pomalé kvůli velkému počtu kontextových přepínačů. Porovnání instancí komplexních typů objektů však nelze provést přímo v PL/SQL bez nějaké další práce.
Aby Oracle mohl vědět, zda jsou instance objektů stejné nebo odlišné, musíme definovat metoda mapování nebo řazení pro typ objektu . Oba typy metod nejsou povoleny, proto je potřeba zvolit tu správnou. Metody MAP fungují rychleji a v našem případě není potřeba nic objednávat, takže do toho:

create or replace TYPE tbl_list_rec2 AS OBJECT (
  l_owner  VARCHAR2(64),
  l_name  VARCHAR2(64),
  map member function get_key return varchar2
);
/

Realizace:

create or replace TYPE BODY tbl_list_rec2 AS 

  map member function get_key return varchar2
  is
  begin
    return l_owner||chr(1)||l_name;
  end;

end;
/

Poté je možné testovat objekty na rovnost v kódu PL/SQL, jako je jednoduchý varchar2 v prvním příkladu z otázky:

declare
  l_object tbl_list2a;
  i        number; 
begin
  l_object := tbl_list2a( tbl_list_rec2('','') );

  for i in 1..100000 loop          
    l_object := l_object MULTISET UNION DISTINCT tbl_list2a(tbl_list_rec2('myOwner','MyTable'));
  end loop;

  for i in l_object.first..  l_object.last loop
    dbms_output.put_line(l_object(i).l_owner || ',' || l_object(i).l_name);
  end loop;  

end;
/