Jak získat oznámení databáze do aplikace C++

Jedním z přístupů je použití pokročilé fronty Oracle . Za tímto účelem musíte nastavit frontu (a tabulku front) a napsat proceduru PL/SQL, která čeká na další zprávu ve frontě.

Strana C++ pak zavolá proceduru PL/SQL, která se vrátí, když dojde k další události.

Na straně Oracle budete muset použít DBMS_SCHEDULER nebo podobné zařízení k vytvoření události , tj. vložit novou zprávu do fronty ve vhodnou dobu.

Je to stále přístup k hlasování. Mezi dvěma událostmi však není absolutně žádná aktivita.

Aktualizace:

Zde je nějaký ukázkový kód.

Počáteční nastavení fronty (zpráva obsahuje číselnou a textovou hodnotu):

grant AQ_ADMINISTRATOR_ROLE to appuser;
grant EXECUTE ON DBMS_AQ to appuser;
grant EXECUTE ON DBMS_AQ to appuser;


CREATE TYPE sample_payload_type AS OBJECT
(
  cmd  VARCHAR2(20),
  id   NUMBER
);


BEGIN
  DBMS_AQADM.CREATE_QUEUE_TABLE (
    queue_table        => 'sample_queue_table',
    queue_payload_type => 'sample_payload_type',
    sort_list          => 'ENQ_TIME',
    compatible         => '10.0'
  );
END;
/

BEGIN
  DBMS_AQADM.CREATE_QUEUE (
    queue_name         => 'sample_queue',
    queue_table        => 'sample_queue_table'
  );

  DBMS_AQADM.START_QUEUE (
    queue_name         => 'sample_queue'
  );
END;
/

Záhlaví balíčku:

create or replace package sample_queue_pkg
as

  procedure get_next_msg(
    i_max_wait      number
   ,o_cmd      out  varchar2
   ,o_id       out  number
  );


  procedure put_msg(
    i_cmd           varchar2
   ,i_id            number
  );

end sample_queue_pkg;
/

Tělo balíčku:

create or replace package body sample_queue_pkg
as

  procedure get_next_msg(
    i_max_wait      number
   ,o_cmd      out  varchar2
   ,o_id       out  number
  )
  is
    dequeue_options dbms_aq.dequeue_options_t;
    message_properties dbms_aq.message_properties_t;
    message_handle RAW(16);
    message sample_payload_type;

    NO_MESSAGE_RECEIVED EXCEPTION;
    PRAGMA EXCEPTION_INIT(NO_MESSAGE_RECEIVED, -25228);

  begin
    dequeue_options.wait := i_max_wait;
    DBMS_AQ.DEQUEUE (
      queue_name => 'appuser.sample_queue',
      dequeue_options => dequeue_options,
      message_properties => message_properties,
      payload => message,
      msgid => message_handle
    );

    o_cmd := message.cmd;
    o_id := message.id;

  exception
    when NO_MESSAGE_RECEIVED then
      o_cmd := null;
      o_id := null;

  end get_next_msg;


  procedure put_msg(
    i_cmd           varchar2
   ,i_id            number
  )
  is
    enqueue_options dbms_aq.enqueue_options_t;
    message_properties dbms_aq.message_properties_t;
    message_handle RAW(16);
    message sample_payload_type;
    message_id NUMBER;

  begin
    message := sample_payload_type(i_cmd, i_id);
    DBMS_AQ.ENQUEUE(
      queue_name => 'appuser.sample_queue',
      enqueue_options => enqueue_options,
      message_properties => message_properties,
    payload => message,
      msgid => message_handle
    );
  end put_msg;

end sample_queue_pkg;
/

Databázový server může odeslat zprávu pomocí následujícího kódu:

sample_queue_pkg.put_msg('run_task', 8234);
commit;

Server C++ může čekat na zprávu (a přijímat je) volající uložený sample_queue_pkg.get_next_msg . Parametr i_max_wait udává maximální dobu čekání na další zprávu v sekundách. Pravděpodobně budete chtít implementovat smyčku, která čeká na další zprávu a zpracovává ji, dokud neobdrží signál, že se server chystá skončit.