Naplňte asociativní pole uvnitř vnořené tabulky

V odpovědi na vaši předchozí otázku jsem zmínil, že naplnění kolekce by bylo těžší s %rowtype pole. Pokud je mi známo, pokud nedeklarujete typ objektu na úrovni SQL místo typu záznamu, nemůžete použít bulk collect za tímto účelem (ačkoli stojí za to zkontrolovat, zda se to ve 12c možná nezměnilo).

Domnívám se, že jste zůstali u používání jednodušší smyčky kurzoru, která vytvoří dvě pole ve vašem typu (tj. %rowtype podpole a rowid pole) samostatně a poté vytvoří kolekci po řádcích:

create or replace package body dat_pkg is

    procedure transform_dat (p_batch_name data_test.batch_name%type)
    is

        cursor cur_dat is
        select rowid, a.*
        from   data_test a
        where  batch_name = p_batch_name;

        l_dat_tst typ_dat_tst;
        l_rec data_test%rowtype;

    begin

        for rec_dat in cur_dat loop
            l_rec.data_id := rec_dat.data_id;
            l_rec.data_value := rec_dat.data_value;
            l_rec.batch_name := rec_dat.batch_name;
            -- or use a counter you increment for this...
            l_dat_tst(l_dat_tst.count + 1).data_rec := l_rec;
            l_dat_tst(l_dat_tst.count).data_rowid := rec_dat.rowid;
        end loop;

        -- Do the Transformation here. Example --            

        for i in 1..l_dat_tst.count loop
            if l_dat_tst(i).data_rec.data_value = 'hello' then
                l_dat_tst(i).data_rec.data_value := 'was hello';
            else            
                l_dat_tst(i).data_rec.data_value := 'was not hello';
            end if;
        end loop;

        -- update the table            
        proc_test (p_dat => l_dat_tst);

    end transform_dat;

    procedure proc_test (p_dat  typ_dat_tst)
    is
    begin

        for i in 1..p_dat.count loop

            update  data_test        
            set     data_value  = p_dat(i).data_rec.data_value  
            where   data_id     = p_dat(i).data_rec.data_id
            and     rowid       = p_dat(i).data_rowid;

        end loop;

    end proc_test;

end dat_pkg;
/    

Jak bylo také diskutováno dříve, odkazy na pole záznamu dílčího pole musí být správně kvalifikovány, takže jsem vložil .data_rec v odkazech v obou postupech. Změnil jsem fiktivní transformaci, abych upravil hodnotu místo ID, protože to znamená, že k žádným aktualizacím nikdy nedojde.

Demo s nějakými fiktivními daty:

insert into data_test values (1, 'hello', 'test');
insert into data_test values (2, 'hello', 'test');
insert into data_test values (3, 'hello', 'exclude');
insert into data_test values (4, 'goodbye', 'test');


exec dat_pkg.transform_dat('test');

select * from data_test;

   DATA_ID DATA_VALUE           BATCH_NAME          
---------- -------------------- --------------------
         1 was hello            test                
         2 was hello            test                
         3 hello                exclude             
         4 was not hello        test