4 Příklady anonymních bloků PL/SQL

V tomto tutoriálu uvádím 4 příklady anonymních bloků PL/SQL, abyste se naučili, jak vytvářet a používat anonymní bloky v databázi Oracle. Anonymní bloky v PL/SQL jsou programy, které nemají žádný příkaz Create Procedure nebo Create Function a neukládají se do databáze Oracle. Anonymní bloky PL/SQL se většinou používají k testování nebo k jednorázovému spuštění programu v databázi Oracle.

1. Anonymní blok PL/SQL pro tisk čísel v opačném pořadí

Následující program PL/SQL vytiskne čísla 0 až 10 v obráceném pořadí s použitím klauzule REVERSE ve smyčce for.

SET SERVEROUTPUT ON;
DECLARE
  counter   NUMBER;
BEGIN
  FOR counter IN REVERSE 0..10 LOOP
    DBMS_OUTPUT.PUT_LINE (counter);
  END LOOP;
END;
/

Výstup

10
9
8
7
6
5
4
3
2
1
0
PL/SQL procedure successfully completed.

2. Tisk Počítání zaměstnanců v oddělení

Následující program PL/SQL bude počítat zaměstnance v oddělení 90. Tabulka je z HR schématu databáze Oracle. Toto schéma si můžete stáhnout z následujícího odkazu Stáhnout schéma HR.

SET SERVEROUTPUT ON;

DECLARE
   emp_count         NUMBER;
   v_department_id   NUMBER := 90;
BEGIN
   SELECT COUNT ( * )
     INTO emp_count
     FROM employees
    WHERE department_id = v_department_id;

   DBMS_OUTPUT.PUT_LINE(   'The employee count is: '
                        || emp_count
                        || ' for the department with an ID of: '
                        || v_department_id);
END;
/

Výstup

The employee count is: 3 for the department with an ID of: 90
PL/SQL procedure successfully completed.

3. Take Input in PL/SQL Anonymous Block and Print

V níže uvedeném příkladu požádá uživatele o zadání ID oddělení a vytiskne počet zaměstnanců v tomto oddělení a také vytiskne název oddělení.

SET SERVEROUTPUT ON;

DECLARE
   dept_id_var   NUMBER (4) := &department_id;
   dept_name     VARCHAR2 (30);
   emp_count     NUMBER;
BEGIN
   SELECT COUNT ( * )
     INTO emp_count
     FROM employees
    WHERE department_id = dept_id_var;

   SELECT department_name
     INTO dept_name
     FROM departments
    WHERE department_id = dept_id_var;

   DBMS_OUTPUT.PUT_LINE(   'There are '
                        || emp_count
                        || ' employees '
                        || 'in the '
                        || dept_name
                        || ' department.');
END;
/

Výstup

Enter value for department_id: 60
old   2:   dept_id_var  NUMBER(4) := &department_id;
new   2:   dept_id_var  NUMBER(4) := 60;
There are 4 employees in the IT department.

PL/SQL procedure successfully completed.

4. Blok PL/SQL s <> Příklad

Následující blok PL/SQL používá štítky pro nadřazený a podřízený blok. Podřízený blok bude přistupovat k proměnné nadřazeného bloku pomocí odkazu na štítek nadřazeného bloku. Program aktualizuje staré ID manažera novým ID manažera pro oddělení.

SET SERVEROUTPUT ON;
<<outer_block>>
DECLARE
   mgr_id       NUMBER (6) := '&current_manager_id';
   dept_count   NUMBER := 0;
BEGIN
   SELECT COUNT ( * )
     INTO dept_count
     FROM departments
    WHERE manager_id = outer_block.mgr_id;

   IF dept_count > 0
   THEN
     <<inner_block>>
      DECLARE
         dept_name   VARCHAR2 (30);
         mgr_id      NUMBER (6) := '&new_manager_id';
      BEGIN
         SELECT department_name
           INTO dept_name
           FROM departments
          WHERE manager_id = outer_block.mgr_id;

         UPDATE departments
            SET manager_id = inner_block.mgr_id
          WHERE manager_id = outer_block.mgr_id;

         DBMS_OUTPUT.PUT_LINE (
            'Department manager ID has been changed for ' || dept_name);
      END inner_block;
   ELSE
      DBMS_OUTPUT.PUT_LINE (
         'There are no departments listed for the manager');
   END IF;
EXCEPTION
   WHEN NO_DATA_FOUND
   THEN
      DBMS_OUTPUT.PUT_LINE (
         'There are no departments listed for the manager');
END outer_block;
/

Výstup

Enter value for current_manager_id: 100
old 3: mgr_id NUMBER (6) := '&current_manager_id';
new 3: mgr_id NUMBER (6) := '100';
Enter value for new_manager_id: 201
old 16: mgr_id NUMBER (6) := '&new_manager_id';
new 16: mgr_id NUMBER (6) := '201';
Department manager ID has been changed for Executive

PL/SQL procedure successfully completed.