Oracle Hledat ve všech tabulkách ve všech sloupcích řetězec

Minimálně musíte zadat dotaz ALL_TAB_COLUMNS, nikoli ALL_TABLES

DECLARE
  match_count integer;
  v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN  
  FOR t IN (SELECT owner, table_name, column_name FROM all_tab_columns) LOOP   
    EXECUTE IMMEDIATE    
      'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
      ' WHERE '||t.column_name||' = :1'   
       INTO match_count  
      USING v_search_string; 
    IF match_count > 0 THEN 
      dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
    END IF; 
  END LOOP;
END;
/

Pokud však hledáte řetězec, téměř jistě byste se chtěli omezit na hledání sloupců, které by mohly řetězec uložit. Nedávalo by smysl například hledat ve sloupci DATE řetězec. A pokud nemáte velké apriorní znalosti o tom, co sloupec BLOB obsahuje, a schopnost analyzovat binární formátování sloupce BLOB, nemělo by smysl hledat ve sloupci BLOB řetězec. Vzhledem k tomu mám podezření, že chcete něco podobného

DECLARE
  match_count integer;
  v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN  
  FOR t IN (SELECT owner,
                   table_name, 
                   column_name 
              FROM all_tab_columns
             WHERE data_type in ('CHAR', 'VARCHAR2', 'NCHAR', 'NVARCHAR2', 
                                 'CLOB', 'NCLOB') ) 
  LOOP   
    BEGIN
      EXECUTE IMMEDIATE    
        'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
        ' WHERE '||t.column_name||' = :1'   
         INTO match_count  
        USING v_search_string; 
      IF match_count > 0 THEN 
        dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
      END IF; 
    EXCEPTION
      WHEN others THEN
        dbms_output.put_line( 'Error encountered trying to read ' ||
                              t.column_name || ' from ' || 
                              t.owner || '.' || t.table_name );
    END;
  END LOOP;
END;
/

Samozřejmě, že to bude šíleně pomalé - jednou byste úplně prohledali každou tabulku pro každý sloupec řetězce v tabulce. Se středně velkými tabulkami a mírným počtem sloupců řetězců to pravděpodobně zabere docela dlouho.