Perl a XPath:chybějící položky v tabulce databáze

Už máte vysvětlení a opravu, ale navrhuji následující změny

• Měli byste se prepare INSERT INTO SQL příkaz a poté execute to ve smyčce. do má mnohem větší režii

• // ( descendant-or-self::node() ) Konstrukce XPath je drahá a měli byste si ji vyhradit pro případy, kdy nemáte ponětí, kde bude prvek v dokumentu, což je velmi vzácné. V tomto případě row1 prvky jsou v /database/row1s/row1 a row2 prvky jsou na row2s/row2 vzhledem k tomu

• Pokud chcete v řetězci v uvozovkách používat znaky uvozovek, je mnohem čistší používat různé oddělovače. Například "My name is \"$name\"" je mnohem lepší jako qq{My name is "$name"}

Zde je verze vašeho programu, která vám může pomoci.

use strict;
use warnings;

use XML::XPath;
use DBI;

my $xp = XML::XPath->new( filename => 'animals4.xml' );

my $dbh = DBI->connect(
   'DBI:mysql:test', 'user', 'pw',
   { RaiseError => 1, PrintError => 0}
) or die "Fehler beim Verbidungsaufbau zum MariaDB-Server: $DBI::err -< $DBI::errstr\n";

my $insert_animal = $dbh->prepare('INSERT INTO animal4 (name, category, type, size) VALUES (?, ?, ?, ?)');

for my $row1 ( $xp->findnodes('/database/row1s/row1') ) {

   my $name     = $row1->getAttribute('name');
   my $category = $row1->getAttribute('category');

   printf qq{Level --- row1 "name" gives: $name\n};

   my @row2 = $xp->findnodes('row2s/row2', $row1);

   if ( @row2 ) {
      for my $row2 ( @row2 ) {

         my $type = $row2->getAttribute('type');
         my $size = $row2->getAttribute('size');

         print qq{Level row2 "type" gives: $type\n};
         print qq{Level row2 "size" gives: $size\n};

         $insert_animal->execute($name, $category, $type, $size);
      }
   }
   else {
      $insert_animal->execute($name, $category, undef, undef);
   }
}

výstup

Level --- row1 "name" gives: fox
Level row2 "type" gives: 1
Level row2 "size" gives: 10
Level row2 "type" gives: 2
Level row2 "size" gives: 8
Level --- row1 "name" gives: horse
Level row2 "type" gives: 3
Level row2 "size" gives: 100
Level --- row1 "name" gives: bee
Level --- row1 "name" gives: wasp