Jak získat soubor z BLOB v Oracle?

V tomto tutoriálu se naučíte, jak získat soubor ze sloupce BLOB v Oracle. Abych uvedl příklad, vytvořil jsem tabulku EXT_FILES v Oracle a následuje struktura tabulky.

CREATE TABLE EXT_FILES
(
FILE_NAME VARCHAR2(1000 BYTE),
FILE_CONTENT BLOB
)
/

Vložte data do výše uvedené tabulky. Pokud nevíte, jak vložit soubor do sloupce BLOB, přečtěte si následující článek Jak vložit soubor do sloupce BLOB tabulky Oracle?

Chcete-li získat soubory ze sloupce BLOB na disk, musíte mít ve schématu vytvořený objekt adresáře Oracle. Chcete-li vytvořit adresář v Oracle, zadejte následující příkaz.

CREATE OR REPLACE DIRECTORY IMGDIR AS 'C:\TEMP\IMAGES';

Níže je uveden příklad Oracle Stored Procedure, který načte záznamy z tabulky EXT_FILES (obsahující data BLOB) pomocí kurzoru a poté extrahuje soubory jeden po druhém do zadaného adresáře.

Příklad uložené procedury Oracle pro získání souboru ze sloupce BLOB v Oracle

CREATE OR REPLACE PROCEDURE get_files_from_blob
IS
l_file UTL_FILE.file_type;
l_buffer RAW (32767);
l_amount BINARY_INTEGER := 32767;
l_pos INTEGER := 1;
l_blob_len INTEGER;
l_blob BLOB;
l_filename ext_files.file_name%TYPE;
/* cursor to get the records from the table */
CURSOR c_files
IS
SELECT file_name, file_content FROM ext_files;
BEGIN
OPEN c_files;

LOOP

FETCH c_files
INTO l_filename, l_blob;

EXIT WHEN c_files%NOTFOUND;

l_blob_len := DBMS_LOB.getlength (l_blob);

/* Change the directory name (IMGDIR) to your Oracle directory object name*/
l_file :=
UTL_FILE.fopen ('IMGDIR',
l_filename,
'wb',
32767);
l_pos := 1;

WHILE l_pos < l_blob_len
LOOP
DBMS_LOB.read (l_blob,
l_amount,
l_pos,
l_buffer);
UTL_FILE.put_raw (l_file, l_buffer, TRUE);
l_pos := l_pos + l_amount;
END LOOP;

UTL_FILE.fclose (l_file);
END LOOP;

CLOSE c_files;
EXCEPTION
WHEN OTHERS
THEN
IF UTL_FILE.is_open (l_file)
THEN
UTL_FILE.fclose (l_file);
END IF;

RAISE;
END;

Test

BEGIN
get_files_from_blob;
END;
/

Výstup

PL/SQL procedure successfully completed.

Nyní můžete zkontrolovat umístění objektu adresáře IMGDIR pro extrahované soubory.

Viz také:

• Extrahujte data BLOB z tabulky Oracle pomocí Toad