Hodnota CLOB v out/return z plsql (zadán neplatný lokátor LOB:ORA-22275)

V tomto okamžiku:

    dbms_lob.loadclobfromfile(
      DEST_LOB     => l_clob

... váš l_clob Parametr OUT nebyl inicializován. Nefunguje ani vytvoření prázdného CLOB (takže i když jste vytvořili l_clob parametr IN OUT by si stále stěžoval) jako dokumentaci pro empty_clob zmínky :

Místo toho můžete použít dočasný CLOB přidáním volání dbms_lob.createtemporary(l_clob, true) než jej zkusíte použít:

...
begin
    l_bfile := bfilename( 'SCHEMES_OF_PS', p_file_name );
    dbms_lob.fileopen( l_bfile );
    dbms_lob.createtemporary(l_clob, true);
    dbms_lob.loadclobfromfile(
      DEST_LOB     => l_clob
      ...

A pak nemusíte při volání zadávat počáteční prázdnou hodnotu:

declare
  myVal clob;
begin
  dbst_load_a_file('Konotop.svg', myVal);
  DBMS_OUTPUT.PUT_LINE(myVal);
end;
/

Toto funguje také jako funkce:

create or replace 
function dbst_load_a_file( p_file_name in varchar2) return clob
as
    l_clob    clob;
    l_bfile   bfile;
    dst_offset  number := 1 ;
    src_offset  number := 1 ;
    lang_ctx    number := DBMS_LOB.DEFAULT_LANG_CTX;
    warning     number;
begin
    l_bfile := bfilename( 'SCHEMES_OF_PS', p_file_name );
    dbms_lob.fileopen( l_bfile );
    dbms_lob.createtemporary(l_clob, true);
    dbms_lob.loadclobfromfile(
      DEST_LOB     => l_clob
    , SRC_BFILE    => l_bfile
    , AMOUNT       => dbms_lob.getlength( l_bfile )
    , DEST_OFFSET  => dst_offset
    , SRC_OFFSET   => src_offset
    , BFILE_CSID   => DBMS_LOB.DEFAULT_CSID
    , LANG_CONTEXT => lang_ctx
    , WARNING      => warning);
    dbms_lob.fileclose( l_bfile );
    return l_clob;
end;
/

select dbst_load_a_file('Konotop.svg') from dual;

Nebo použijte v insert jako ve vaší upravené otázce.