Najděte a nahraďte řetězec uvnitř BLOB for Work nebo souboru Excel

Soubory Microsoft Word a Excel nejsou textové soubory, ve kterých můžete pouze nahradit text a které rozhodně nebudou fungovat s BLOB . docx a xlsx soubory jsou ve skutečnosti soubory zip (zkuste změnit příponu souboru a rozbalit, abyste se sami přesvědčili), které obsahují XML definici dokumentu. Takže budete muset:

1. Rozbalte soubor
2. Převeďte soubor, který je třeba změnit, z BLOB do CLOB
3. Upravte obsah správného souboru XML
4. Převeďte soubor zpět na BLOB z CLOB
5. Přidejte upravený soubor zpět do souboru zip

Níže uvedený kód jsem napsal jako příklad toho, jak provést náhradu docx soubor. Pro xlsx Každý list aplikace Excel je obsažen v jiném souboru XML, takže budete muset kód mírně upravit, aby fungoval s oběma typy souborů.

Kód používá APEX_ZIP balíček, který výrazně zjednodušuje práci se soubory zip a také o něco srozumitelnější kód příkladu, co se děje. Pokud nemáte nainstalovaný APEX, budete muset zjistit, jak provést rozbalení/rezipování souborů pomocí balíčků Oracle, které máte.

DECLARE
    l_old_file       BLOB;
    l_new_file       BLOB;
    l_files          apex_zip.t_files;
    l_document       BLOB;
    l_clob           CLOB;
    l_dest_offsset   INTEGER;
    l_src_offsset    INTEGER;
    l_lang_context   INTEGER := DBMS_LOB.default_lang_ctx;
    l_warning        INTEGER;
BEGIN
    -- Get the blob you want to "correct"
    SELECT blob_content
      INTO l_old_file
      FROM apex_application_temp_files
     WHERE ROWNUM = 1;

    -- Get a list of all the file names contained within the zip
    l_files := apex_zip.get_files (l_old_file);

    -- Loop through all the files adding each one to the new zip
    FOR i IN l_files.FIRST .. l_files.LAST
    LOOP
        l_document := apex_zip.get_file_content (l_old_file, l_files (i));

        IF l_files (i) = 'word/document.xml'
        THEN
            -- if the file name is word/document.xml then make the changes to it
            
            DBMS_LOB.createTemporary (lob_loc => l_clob, cache => FALSE);

            l_dest_offsset := 1;
            l_src_offsset := 1;

            DBMS_LOB.converttoclob (dest_lob       => l_clob,
                                    src_blob       => l_document,
                                    amount         => DBMS_LOB.lobmaxsize,
                                    dest_offset    => l_dest_offsset,
                                    src_offset     => l_src_offsset,
                                    blob_csid      => DBMS_LOB.default_csid,
                                    lang_context   => l_lang_context,
                                    warning        => l_warning);

            --------------------
            -- This is where you would do any replacements
            --------------------
            l_clob := REPLACE (l_clob, 'www.google.co.uk', 'www.google.com');
            --------------------

            l_dest_offsset := 1;
            l_src_offsset := 1;

            DBMS_LOB.CONVERTTOBLOB (dest_lob       => l_document,
                                    src_clob       => l_clob,
                                    amount         => DBMS_LOB.lobmaxsize,
                                    dest_offset    => l_dest_offsset,
                                    src_offset     => l_src_offsset,
                                    blob_csid      => DBMS_LOB.default_csid,
                                    lang_context   => l_lang_context,
                                    warning        => l_warning);
        END IF;

        apex_zip.add_file (l_new_file, l_files (i), l_document);
    END LOOP;

    apex_zip.finish (l_new_file);
    --Do whatever you want with the "new" file here
END;