Rozdělení hodnot s oddělovači ve sloupci SQL do více řádků

Pokud používáte SQL Server 2016+

Můžete použít nový STRING_SPLIT funkce, o které jsem blogoval zde, a o této funkci psal Brent Ozar zde.

SELECT s.[message-id], f.value
  FROM dbo.SourceData AS s
  CROSS APPLY STRING_SPLIT(s.[recipient-address], ';') as f;

Pokud stále používáte verzi starší než SQL Server 2016

Vytvořte funkci rozdělení. Toto je jen jeden z mnoha příkladů:

CREATE FUNCTION dbo.SplitStrings
(
    @List       NVARCHAR(MAX),
    @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
AS
    RETURN (SELECT Number = ROW_NUMBER() OVER (ORDER BY Number),
        Item FROM (SELECT Number, Item = LTRIM(RTRIM(SUBSTRING(@List, Number, 
        CHARINDEX(@Delimiter, @List + @Delimiter, Number) - Number)))
    FROM (SELECT ROW_NUMBER() OVER (ORDER BY s1.[object_id])
        FROM sys.all_objects AS s1 CROSS APPLY sys.all_objects) AS n(Number)
    WHERE Number <= CONVERT(INT, LEN(@List))
        AND SUBSTRING(@Delimiter + @List, Number, 1) = @Delimiter
    ) AS y);
GO

O několika dalších jsem diskutoval zde, zde a je to lepší přístup než rozdělení na prvním místě zde.

Nyní můžete extrapolovat jednoduše:

SELECT s.[message-id], f.Item
  FROM dbo.SourceData AS s
  CROSS APPLY dbo.SplitStrings(s.[recipient-address], ';') as f;

Také doporučuji nevkládat pomlčky do názvů sloupců. To znamená, že je vždy musíte umístit do [square brackets] .